Funções matemáticas
Essa categoria contém as funções matemáticas do Calc. Para abrir o Assistente de funções, escolha Inserir - Função.
Função AGREGAR
Esta função retorna o resultado agregado de cálculos de um intervalo. A função AGREGAR permite ignorar linhas ocultas e valores de erro, bem como agregar outras funções, tais como aquelas que são listadas abaixo.
Função SOMASES
Retorna a soma dos valores das células de um intervalo que conferem critérios em vários intervalos.
ABS
Retorna o valor absoluto de um número.
Sintaxe
ABS(Número)
Número é o valor cujo valor absoluto será calculado. O valor absoluto de um número é seu valor sem o sinal de + ou -.
Exemplo
=ABS(-56) retorna 56.
=ABS(12) retorna 12.
=ABS(0) retorna 0.
ACOS
Retorna o arco-cosseno (inverso do cosseno trigonométrico) de um número.
Sintaxe
ACOS(Número)
Essa função retorna o cosseno trigonométrico inverso (arco cosseno) de Número, isto é, o ângulo (em radianos) cujo cosseno é Número. O ângulo retornado está entre 0 e PI.
Para obter o ângulo em graus, utilize a função GRAUS.
Exemplo
=ACOS(-1) retorna 3,14159265358979 (PI radianos)
=GRAUS(ACOS(0,5)) retorna 60. O cosseno de 60 graus é 0,5.
ACOSH
Retorna o cosseno hiperbólico inverso (arco cosseno hiperbólico) de um número.
Sintaxe
ACOSH(Número)
Essa função retorna o cosseno hiperbólico inverso (arco cosseno hiperbólico) de Número, isto é, o número cujo cosseno hiperbólico é Número.
Número deve ser maior ou igual a 1.
Exemplo
=ACOSH(1) retorna 0.
=ACOSH(COSH(4)) retorna 4.
ACOT
Retorna a cotangente inversa (arco-cotangente) do número.
Sintaxe
ACOT(Número)
Essa função retorna a cotangente trigonométrica inversa (arco cotangente) de Número, isto é, o ângulo (em radianos) cuja cotangente é Número. O ângulo retornado será entre 0 e PI.
Para obter o ângulo em graus, utilize a função GRAUS.
Exemplo
=ACOT(1) retorna 0,785398163397448 (PI/4 radianos).
=GRAUS(ACOT(1)) retorna 45. A cotangente de 45 graus é 1.
ACOTH
Retorna a cotangente hiperbólica inversa (arco cotangente hiperbólica) do número dado.
Sintaxe
ACOTH(Número)
Essa função retorna a cotangente hiperbólica inversa (arco-cotangente hiperbólica) de Número, isto é, o número cuja cotangente hiperbólica é Número.
Ocorrerá um erro caso Número estiver entre -1 e +1 inclusive.
Exemplo
=ACOTH(1,1) retorna a cotangente hiperbólica inversa (arco cotangente hiperbólica) de 1,1, aproximadamente 1,52226.
ALEATÓRIO
Retorna um número aleatório entre 0 e 1.
Sintaxe
ALEATÓRIO()
Essa função produz um novo número aleatório a cada vez que o Calc recalcular. Para forçar o Calc a recalcular manualmente, pressione F9.
Para gerar números aleatórios que nunca serão recalculados, copie as células contendo a função ALEATÓRIO() e utilize
(com e desmarcada e marcado).Exemplo
=ALEATÓRIO() retorna um número aleatório entre 0 e 1.
ALEATÓRIOENTRE
Retorna um número inteiro aleatório dentro de um intervalo especificado.
Sintaxe
ALEATÓRIOENTRE (Inferior; Superior)
Retorna um número aleatório inteiro entre os inteiros Inferior e Superior (ambos inclusos).
Essa função produz um novo número aleatório a cada vez que o Calc recalcular. Para forçar o Calc a recalcular manualmente, pressione Shift+CommandCtrl+F9.
Para gerar números aleatórios sem repetição. copie as células contendo essa função e utilize
(com e desmarcada e marcados).Exemplo
=ALEATÓRIOENTRE(20;30) retorna um inteiro entre 20 e 30.
ARRED
Arredonda um número para um determinado número de casas decimais.
Sintaxe
ARRED(Número; Cont)
Retorna Número arredondado a Cont casas decimais. Se Cont for omitido ou for zero, a função arredonda para o inteiro mais próximo. Se Cont for negativo, a função arredonda para a dezena, centena, milhar, etc... mais próximo.
Essa função arredonda ao inteiro mais próximo. Veja ARREDONDAR.PARA.BAIXO e ARREDONDAR.PARA.CIMA para funções alternativas relacionadas.
Exemplo
=ARRED(2,348;2) retorna 2,35
=ARRED(-32,4834;3) retorna -32,483. Mude o formato da célula para ver todas as decimais.
=ARRED(2,348;0) retorna 2.
=ARRED(2,5) retorna 3.
=ARRED(987,65;-2) retorna 1000.
ARREDMULTB
Arredonda um número para baixo para o múltiplo da precisão mais próximo.
Sintaxe
ARREDMULTB(Número; Precisão; Modo)
Número é o número que será arredondado para baixo.
Precisão é o valor para cujo múltiplo o número será arredondado para baixo.
Modo é um parâmetro opcional. Se Modo for passado e não for igual a zero, e se os parâmetros Número e Precisão forem negativos, então o arredondamento será feito com base no valor absoluto do número, ou seja, os números negativos serão arredondados para um valor mais próximo de zero. Se o parâmetro Modo for igual a zero ou omitido, os números negativos serão arredondados para um valor mais distante de zero.
Se a planilha é exportada para o MS Excel, a função ARREDMULTB é exportada para a função equivalente ARREDMULTB.MAT que existe desde o Excel 2013. Se planeja utilizar a planilha com versões anteriores do Excel, utilize seja ARREDMULTB.PRECISO que existe desde o Excel 2010, ou ARREDMULTB.XCL que é exportado como função ARREDMULTB compatível com todas as versões do Excel. Note que ARREDMULTB.XCL sempre arredonda em direção a zero. |
Exemplo
=ARREDMULTB( -11;-2) retorna -12
=ARREDMULTB( -11;-2;0) retorna -12
=ARREDMULTB( -11;-2;1) retorna -10
ARREDMULTB.PRECISO
Arredonda um número para baixo até o mais próximo múltiplo de precisão, independentemente do sinal do número.
Sintaxe
ARREDMULTB.PRECISO(Número; Precisão)
Número é o número que será arredondado para baixo.
Precisão é o valor para cujo múltiplo o número será arredondado para baixo.
Exemplo
=ARREDMULTB.PRECISO( -11;-2) retorna -12
ARREDONDAR.PARA.BAIXO
Arredonda um número para baixo, conforme a casa decimal especificada.
Sintaxe
ARREDONDAR.PARA.BAIXO(Número; Cont)
Retorna Número arredondado para baixo (para zero) até Cont casas decimais. Se Cont for omitido ou for igual a zero, a função arredonda até um inteiro. Se Cont for negativo, a função arredonda para baixo para a próxima dezena, centena, milhar, etc.
Esta função arredonda em direção a zero. Veja as alternativas ARREDONDAR.PARA.CIMA e ARRED.
Exemplo
=ARREDONDAR.PARA.BAIXO(1,234;2) retorna 1,23.
=ARREDONDAR.PARA.BAIXO(45,67;0) retorna 45.
=ARREDONDAR.PARA.BAIXO(-45,67) retorna -45.
=ARREDONDAR.PARA.BAIXO(987,65;-2) retorna 900.
ARREDONDAR.PARA.CIMA
Arredonda um número para cima, afastando de zero, conforme a casa decimal especificada.
Sintaxe
ARREDONDAR.PARA.CIMA(Número; Cont)
Retorna Número arredondado para cima (afastando de zero) até Cont casas decimais. Se Cont for omitido ou for zero, a função arredonda para cima até um inteiro. Se Cont for negativo, a função arredonda para cima à próxima dezena, centena, milhar, etc.
Essa função arredonda para cima. Veja as alternativas ARREDONDAR.PARA.BAIXO e ARRED.
Exemplo
=ARREDONDAR.PARA.CIMA(1,1111;2) retorna 1,12.
=ARREDONDAR.PARA.CIMA(1,2345;1) retorna 1,3.
=ARREDONDAR.PARA.CIMA(45,67;0) retorna 46.
=ARREDONDAR.PARA.CIMA(-45,67) retorna -46.
=ARREDONDAR.PARA.CIMA(987,65;-2) retorna 1000.
ASEN
Retorna o seno trigonométrico inverso (arco seno) de um número.
Sintaxe
ASEN(Número)
Essa função retorna o seno trigonométrico inverso (arco seno trigonométrico) de Número, isto é, o ângulo (em radianos) cujo seno é Número. O ângulo retornado está entre -PI/2 e +PI/2.
Para obter o ângulo em graus, utilize a função GRAUS.
Exemplo
=ASEN(0) retorna 0.
=ASEN(1) retorna 1,5707963267949 (PI/2 radianos).
=GRAUS(ASEN(0,5)) retorna 30. O seno de 30 graus é 0,5.
ASENH
Retorna o seno hiperbólico inverso (arco-seno hiperbólico) de um número.
Sintaxe
ASENH(Número)
Essa função retorna seno hiperbólico inverso (arco seno hiperbólico) de Número, isto é, o número cujo seno hiperbólico é Número.
Exemplo
=ASENH(-90) retorna aproximadamente -5,1929877.
=ASENH(SENH(4)) retorna 4.
ATAN
Retorna a tangente trigonométrica inversa (arco tangente) de um número.
Sintaxe
ATAN(Número)
Essa função retorna a tangente trigonométrica inversa (arco-tangente) de Número, isto é, o ângulo (em radianos) cuja tangente é Número. O ângulo retornado está entre -PI/2 e PI/2.
Para obter o ângulo em graus, utilize a função GRAUS.
Exemplo
=ATAN(1) retorna 0,785398163397448 (PI/4 radianos).
=GRAUS(ATAN(1)) retorna 45. A tangente de 45 graus é 1.
ATAN2
Retorna a tangente trigonométrica inversa (arco tangente) das coordenadas x e y especificadas.
Sintaxe
ATAN2(NúmeroX; NúmeroY)
NúmeroX é o valor da coordenada x.
NúmeroY é o valor da coordenada y.
ATAN2 retorna a tangente trigonométrica inversa (arco tangente), isto é, o ângulo (em radianos) entre o eixo x e uma linha do ponto NúmeroX, NúmeroY até a origem. O ângulo retornado está entre -PI e +PI.
Para obter o ângulo em graus, utilize a função GRAUS.
Exemplo
=ATAN2(20;20) retorna 0,785398163397448 (PI/4 radianos).
=GRAUS(ATAN2(12,3;12,3)) retorna 45. A tangente de 45 graus é 1.
ATANH
Retorna a tangente hiperbólica inversa (arco tangente hiperbólica) de um número.
Sintaxe
ATANH(Número)
Essa função retorna a tangente hiperbólica inversa (arco tangente hiperbólica) de Número, isto é, o número cuja tangente hiperbólica é Número.
Número deve obedecer a condição -1 < número < 1.
Exemplo
=ATANH(0) retorna 0.
COMBIN
Retorna o número de combinações para elementos sem repetição.
Sintaxe
COMBIN(Cont1; Cont2)
Cont1 é o número de itens no conjunto.
Cont2 é o número de itens a escolher do conjunto.
COMBIN retorna o número de maneiras ordenadas para escolher esses itens. Por exemplo, se houver 3 itens A, B e C em um conjunto, você pode escolher 2 itens de 3 maneiras diferentes, a saber, AB, AC e BC.
COMBIN implementa a fórmula: Cont1!/(Cont2!*(Cont1-Cont2)!)
Exemplo
=COMBIN(3;2) retorna 3.
COMBINA
Retorna o número de combinações de um subconjunto de itens incluindo repetições.
Sintaxe
COMBINA(Cont1; Cont2)
Cont1 é o número de itens no conjunto.
Cont2 é o número de itens a escolher do conjunto.
COMBINA retorna o número de maneiras únicas de se escolher esses elementos, onde a ordem de escolha é irrelevante, e a repetição dos itens é permitida. Por exemplo, se há 3 itens A,B e C em um conjunto, você pode escolher 2 elementos de 6 maneiras diferentes, a saber: AB, BA, AC, CA, BC e CB.
COMBINA implementa a fórmula: (Count1+Count2-1)! / (Count2!(Count1-1)!)
Exemplo
=COMBINA(3;2) retorna 6.
CONVERTEREURO
Converte antigas moedas dos países europeus para Euros e vice-versa.
Sintaxe
CONVERTEREURO(Valor; "De_moeda"; "Para_moeda", Precisão_total, Precisão_triangulação)
Valor é o montante da moeda a converter.
De_moeda e Para_moeda são as unidades monetárias a converter em Euros e vice-versa. Devem ser no formato texto, representando a abreviação oficial da moeda (por exemplo, "EUR"). As taxas (por Euro) foram definidas pela Comissão Europeia.
Precisão_total é opcional. Se omitido ou falso, o resultado será arredondado de acordo com as decimais da moeda de destino. Se Precisão_total for verdadeiro, o resultado não será arredondado.
Precisão_triangulação é opcional. Se Precisão_triangulação for fornecida e >=3, o resultado intermediário de uma conversão triangular (moeda1,EUR,moeda2) será arredondado para esta precisão. Se Precisão_triangulação for omitida, o resultado intermediário não será arredondado. Também, se Para_moeda for "EUR", Precisão_triangulação será utilizada como se a triangulação fosse necessária e a conversão de EUR para EUR fosse aplicada.
Exemplos
=CONVERTEREURO(100;"ATS";"EUR") converte 100 xelins austríacos em Euros.
=CONVERTEREURO(100;"EUR";"DEM") converte 100 Euros em marcos alemães.
CONVERTER_OOO
Converte um valor de uma unidade de medida para outra unidade de medida. Os fatores de conversão estão em uma lista na configuração.
Em dado momento a lista de fatores de conversão incluiu as moedas europeias legadas e o Euro (veja os exemplos abaixo). Sugerimos utilizar a nova função CONVERTEREURO para converter estas moedas.
Sintaxe
CONVERT_OOO(valor;"texto";"texto")
Exemplo
=CONVERT_OOO(100;"ATS";"EUR") retorna o valor de 100 Schillings Austríacos em Euros.
=CONVERT_OOO(100;"EUR";"DEM") converte 100 Euros em Marcos Alemães.
COS
Retorna o cosseno do ângulo (em radianos).
Sintaxe
COS(Número)
Retorna o cosseno (trigonométrico) do ângulo Número, em radianos.
Para retornar o cosseno de um ângulo em graus, utilize a função RADIANOS.
Exemplos
=COS(PI()*2) retorna 1, que é o cosseno de 2*PI radianos.
=COS(RADIANOS(60)) retorna 0,5, que é o cosseno de 60 graus.
COSEC
Retorna a cossecante de um ângulo (em radianos). A cossecante de um ângulo é equivalente a 1 dividido pelo seno do ângulo
Sintaxe
COSEC(ângulo)
Retorna a cossecante (trigonométrica) de Número, o ângulo em radianos.
Para retornar a cossecante de um ângulo em graus, utilize a função RADIANOS.
Exemplos
=COSEC(PI()/4) retorna aproximadamente 1,4142135624 que é o inverso do seno de PI/4 radianos.
=COSEC(RADIANOS(30)) retorna 2, que é a cossecante de 30 graus.
COSECH
Retorna a cossecante hiperbólica de um número.
Sintaxe
COSECH(Número)
Retorna a cossecante hiperbólica de Número.
Exemplo
=COSECH(1) retorna aproximadamente 0.8509181282, que é a cossecante hiperbólica de 1.
COSH
Retorna o cosseno hiperbólico de um número.
Sintaxe
COSH(Número)
Retorna o cosseno hiperbólico de Número.
Exemplo
=COSH(0) retorna 1, o cosseno hiperbólico de 0.
COT
Retorna a cotangente do ângulo (em radianos).
Sintaxe
COT(Número)
Retorna a cotangente (trigonométrica) do ângulo em radianos Número.
Para obter a cotangente de um ângulo em graus, utilize a função RADIANOS.
A cotangente de um ângulo é equivalente a 1 dividido pela tangente do ângulo.
Exemplos:
=COT(PI()/4) retorna 1, a cotangente de PI/4 radianos.
=COT(RADIANOS(45)) retorna 1, a cotangente de 45 graus.
COTH
Retorna a cotangente hiperbólica de um número determinado (ângulo).
Sintaxe
COTH(Número)
Retorna a cotangente hiperbólica de Número.
Exemplo
=COTH(1) retorna a cotangente hiperbólica de 1, aproximadamente 1,3130.
EXP
Retorna ℇ elevado à potência de um número. A constante de Euler (ℇ) vale aproximadamente 2,71828182845904.
Sintaxe
EXP(Número)
Número é a potência à qual ℇ será elevado.
Exemplo
=EXP(1) retorna 2,71828182845904, a constante de Euler (ℇ) na precisão numérica do Calc.
FATORIAL
Retorna o fatorial de um número.
Sintaxe
FATORIAL(Número)
Retorna Número!, o fatorial de Número, calculado como 1*2*3*4*...*Número.
=FATORIAL(0) retorna 1 por definição.
O fatorial de um número negativo retorna o erro "argumento inválido".
Exemplo
=FATORIAL(3) retorna 6.
=FATORIAL(0) retorna 1.
GRAUS
Converte radianos em graus.
Sintaxe
GRAUS(Número)
Número é o ângulo em radianos a converter para graus.
Exemplo
=GRAUS(PI()) retorna 180 graus.
INT
Arredonda um número para baixo até o inteiro mais próximo.
Sintaxe
INT(Número)
Retorna Número arredondado ao próximo inteiro para baixo.
Números negativos são arredondados para o inteiro inferior.
Exemplo
=INT(5,7) retorna 5.
=INT(-1.3) retorna -2.
ISO.TETO
Arredonda um número para o mais próximo múltiplo da Precisão, independente do sinal dela.
Sintaxe
ISO.TETO(Número; Precisão)
Número (obrigatório) é o número que deverá ser arredondado para cima.
Precisão (opcional) é o número para cujo múltiplo o valor será arredondado.
Exemplo
=ISO.TETO(-11;-2) retorna -10
LN
Retorna o logaritmo natural de um número na base neperiana. A constante de Euler (ℇ) vale aproximadamente 2,71828182845904.
Sintaxe
LN(Número)
Número é o valor cujo logaritmo natural será calculado.
Exemplo
=LN(3) retorna o logaritmo natural de 3 (aproximadamente 1,0986).
=LN(EXP(321)) retorna 321.
LOG
Retorna o logaritmo de um número em uma base determinada.
Sintaxe
LOG(Número; Base)
Número é o valor cujo logaritmo será calculado.
Base (opcional) é a base de cálculo do logaritmo. Se omitida, a base 10 será considerada.
Exemplo
=LOG(10;3) retorna o logaritmo na base 3 de 10 (aproximadamente 2,0959).
=LOG(7^4;7) retorna 4.
LOG10
Retorna o logaritmo de um número na base 10.
Sintaxe
LOG10(Número)
Retorna o logaritmo na base 10 de Número.
Exemplo
=LOG10(5) retorna o logaritmo na base 10 de 5 (aproximadamente 0,69897).
MARRED
Retorna um número arredondado ao mais próximo múltiplo de outro número.
Sintaxe
MARRED(Número; Múltiplo)
Retorna Número arredondado ao próximo múltiplo de Múltiplo.
Uma implementação alternativa poderia ser Múltiplo * ARRED(Número/Múltiplo).
Exemplo
=MARRED(15,5;3) retorna 15, já que 15,5 é mais próximo de 15 (= 3*5) que de 18 (= 3*6).
=MARRED(1,4;0,5) retorna 1,5 (= 0,5*3).
MDC
Retorna o maior divisor comum de dois ou mais inteiros.
O máximo divisor comum é o maior inteiro positivo que dividirá, sem restos, cada um dos inteiros fornecidos.
Sintaxe
MDC(Inteiro1; Inteiro2; ...; Inteiro30)
Inteiro1 a 30 são até 30 inteiros cujo maior divisor comum será calculado.
Exemplo
=MDC(16;32;24) retorna 8, por que 8 é o maior número que pode dividir 16, 24 e 32 sem deixar resto.
=MDC(B1:B3) onde as células B1, B2, B3 contém 9, 12, 9 retorna 3.
MDC_EXCEL2003
O resultado é o maior divisor comum de uma lista de números.
Sintaxe
MDC_EXCEL2003(Número(s))
Número(s) é uma lista de até 30 números.
Exemplo
=GCD_EXCEL2003(5;15;25) retorna 5.
MMC
Retorna o mínimo múltiplo comum de um ou mais números inteiros.
Sintaxe
MMC(Inteiro1; Inteiro2; ...; Inteiro30)
Inteiro1 a 30 são até 30 inteiros cujo mínimo múltiplo comum será calculado.
Exemplo
Ao entrar os números 512;1024 e 2000 nas caixas de texto 1;2 e 3, 128000 será o resultado.
MMC_EXCEL2003
O resultado será o mínimo múltiplo comum de uma lista de números.
Sintaxe
MMC_EXCEL2003(Números(s))
Número(s) é uma lista de até 30 números.
Exemplo
=MMC_EXCEL2003(5;15;25) retorna 75.
MOD
Retorna o resto da divisão euclidiana de dois inteiros.
Sintaxe
MOD(Dividendo; Divisor)
Para argumentos inteiros essa função retorna Dividendo modulo Divisor, isto é, o resto quando Dividendo for dividido por Divisor.
Essa função é implementada como Dividendo - Divisor * INT(Dividendo/Divisor) , e essa fórmula retorna um resultado caso os argumentos não sejam inteiros.
Exemplo
=MOD(22;3) retorna 1, o resto da divisão inteira de 22 por 3.
=MOD(11,25;2,5) retorna 1,25.
MULT
Multiplica todos os números dados como argumentos e retorna o produto.
Sintaxe
MULT(Número1; Número2; ...; Número30)
Número1 a 30 são até 30 argumentos cujo produto será calculado.
MULT retorna o produto Número1*Número2*Número3* ...
Exemplo
=MULT(2;3;4) retorna 24.
MULTINOMIAL
Retorna o fatorial da soma dos argumentos, dividido pelo produto dos fatoriais dos argumentos.
Sintaxe
MULTINOMIAL(Números(s))
Número(s) é uma lista de até 30 números.
Exemplo
=MULTINOMIAL(F11:H11) retorna 1260, onde F11 a H11 contém os valores 2, 3 e 4. Isso corresponde à fórmula =(2+3+4)! / (2!*3!*4!)
PAR
Arredonda um número positivo para o número inteiro par superior mais próximo e um número negativo para um número inteiro par inferior mais próximo.
Sintaxe
PAR(Número)
Retorna Número arredondado para o próximo inteiro par, para cima.
Exemplos
=PAR(2.3) retorna 4.
=PAR(2) retorna 2.
=ÉPAR(0) retorna 0.
=PAR(-0,5) retorna -2.
PI
Retorna 3,14159265358979, o valor da constante matemática PI com 14 casas decimais.
Sintaxe
PI()
Exemplo
=PI() retorna 3,14159265358979.
POTÊNCIA
Retorna um número elevado a outro número.
Sintaxe
POTÊNCIA(Base; Expoente)
Retorna Base elevada a potência de Expoente.
O mesmo resultado pode ser obtido ao usar o operador de exponenciação ^:
Base^Potência
Exemplo
=POTÊNCIA(4;3) retorna 64, que é 4 elevado a 3.
=4^3 também retorna 4 elevado à potência 3.
QUOCIENTE
Retorna a parte inteira de uma divisão.
Sintaxe
QUOCIENTE(Numerador; Denominador)
Retorna a parte inteira de Numerador dividida por Denominador.
QUOCIENTE é equivalente a INT(numerador/denominador), a não ser que possa relatar erros com códigos de erros diferentes.
Exemplo
=QUOCIENTE(11;3) retorna 3. O resto 2 é descartado.
RADIANOS
Converte graus em radianos.
Sintaxe
RADIANOS(Número)
Número é o ângulo em graus a converter para radianos.
Exemplo
=RADIANOS(90) retorna 1,5707963267949, que é PI/2 na precisão do Calc.
RAIZ
Retorna a raiz quadrada positiva de um número.
Sintaxe
RAIZ (Número)
Retorna a raiz quadrada positiva de Número.
Número deve ser positivo.
Exemplo
=RAIZ(16) retorna 4.
=RAIZ(-16) retorna um erro de argumento inválido.
RAIZPI
Retorna a raiz quadrada de um número multiplicado por PI.
Sintaxe
RAIZPI (Número)
Retorna a raiz quadrada de (PI multiplicado por Número).
Isso é equivalente a RAIZ(PI()*Número).
Exemplo
=RAIZPI(2) retorna a raiz quadrada de (2PI), aproximadamente 2,506628.
SEC
Retorna a secante de um ângulo (em radianos). A secante de um ângulo é equivalente a 1 dividido pelo cosseno desse ângulo
Sintaxe
SEC(Número)
Retorna a secante de Número expresso em radianos.
Para retornar a secante de um ângulo em graus, utilize a função RADIANOS.
Exemplos
=SEC(PI()/4) retorna aproximadamente 1,4142135624, que é o inverso do cosseno de PI/4 radianos.
=SEC(RADIANOS(60)) retorna 2, que é a secante de 60 graus.
SECH
Retorna a secante hiperbólica de número.
Sintaxe
SECH(Número)
Retorna a secante hiperbólica de Número.
Exemplo
=SECH(0) retorna 1, que é a secante hiperbólica de 0.
SEN
Retorna o seno do ângulo especificado (em radianos).
Sintaxe
SEN(Número)
Retorna o seno (trigonométrico) do ângulo Número, ângulos em radianos.
Para retornar o seno de um ângulo em graus, utilize a função RADIANOS.
Exemplo
=SEN(PI()/2) retorna 1, o seno de PI/2 radianos.
=SEN(RADIANOS(30)) retorna 0,5, o seno de 30 graus.
SENH
Retorna o seno hiperbólico de um número.
Sintaxe
SENH(Número)
Retorna o seno hiperbólico de Número.
Exemplo
=SENH(0) retorna 0, o seno hiperbólico de 0.
SINAL
Retorna o sinal de um número. Retorna 1 se o número é positivo, -1 se o número é negativo e 0 se o número é zero.
Sintaxe
SINAL(Número)
Número é o número cujo sinal será determinado.
Exemplo
=SINAL(3,4) retorna 1.
=SINAL(-4.5) retorna -1.
SOMA
Adiciona todos os números em um intervalo de células.
Sintaxe
SOMA(Número1; Número2; ...; Número30)
Número 1 a Número 30 são até 30 argumentos cuja soma será calculada.
Exemplo
Ao entrar com os números 2; 3 e 4 nas caixas Número 1; 2 e 3 , então 9 será o resultado.
=SOMA(A1;A3;B5) calcula a soma das três células. =SOMA(A1:E10) calcula a soma de todas as células no intervalo A1 até E10.
As condições vinculadas por E podem ser utilizadas com a função SOMA() da seguinte maneira:
Exemplo prático: Você inseriu faturas numa tabela. A coluna A contém a data da fatura, a coluna B o valor. Você deseja achar a fórmula para obter o faturamento de um mês específico, por exemplo, o faturamento para o período >= 1/1/2008 até < 1/2/2008. O intervalo de datas é A1:A40, o intervalo de valores é B1:B40. C1 contém a data de início,01/01/2008, das faturas a serem incluídas da conta e C2 a data 01/02/2008 das faturas a desconsiderar.
Insira a seguinte fórmula como uma fórmula de matriz:
=SOMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)
Para inserir esta fórmula como fórmula de matriz, você deve pressionar Shift+Command +Ctrl+ Enter em vez de simplesmente pressionar a tecla Enter para fechar a fórmula. Em seguida, a fórmula será exibida entre chaves na barra de Fórmula.
{=SOMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}
A fórmula está baseada no fato que o resultado de uma comparação é 1 se o critério for confirmado e 0 caso contrário. O resultado da comparação individual será tratado como matriz e usado numa multiplicação de matriz, e no final os valores individuais serão somados para obter a matriz resultante.
SOMAQUAD
Se você deseja calcular a soma dos quadrados dos números (totalizando os quadrados dos argumentos), insira isso nos campos de texto.
Sintaxe
SOMAQUAD(Número1; Número2; ...; Número30)
Número1 a 30 são até 30 números cuja soma dos quadrados será calculada.
Exemplo
Ao entrar com os números 2; 3 e 4 nas caixas de texto Número 1; 2 e 3, o resultado é 29.
SOMASE
Adiciona as células quando especificadas por critérios dados. Essa função é utilizada para localizar um intervalo quando você procura por um valor determinado.
Sintaxe
SOMASE(Intervalo;, Critérios; SomaIntervalo)
Intervalo é o intervalo onde os critérios serão aplicados.
Critérios é a célula contendo o critério de pesquisa, ou o próprio critério de pesquisa. Se o critério for escrito na fórmula, terá de ser envolto por aspas duplas.
SomaIntervalo é o intervalo onde os valores serão somados. Se este parâmetro não foi indicado, os valores encontrados no Intervalo serão somados.
SOMASE suporta o operador de concatenação de referências (~) somente nos parâmetros de critérios, e somente se o parâmetro opcional SomaIntervalo não for fornecido. |
Exemplo
Para somar somente os números negativos: =SOMASE(A1:A10;"<0")
=SOMASE(A1:A10;">0";B1:10) - soma os valores do intervalo B1:B10 somente quando os valores correspondentes no intervalo A1:A10 forem >0.
Consulte CONT.SE() para obter mais exemplos de sintaxes que podem ser usadas com SOMASE().
SOMASEQUÊNCIA
Soma os primeiros termos de uma série de potências.
SOMASEQUÊNCIA(x;n;m;coeficientes) = coeficiente_1*x^n + coeficiente_2*x^(n+m) + coeficiente_3*x^(n+2m) +...+ coeficiente_i*x^(n+(i-1)m)
Sintaxe
SOMASEQUÊNCIA(X; N; M; Coeficientes)
X é o valor de entrada da série de potências.
N é a potência inicial
M é o incremento para aumentar N
Coeficientes é uma série de coeficientes. Para cada coeficiente a soma da série é estendida de uma seção.
SUBTOTAL
Calcula subtotais. Se um intervalo já contiver subtotais, eles não serão usados para outros cálculos. Utilize esta função com os Autofiltros para considerar apenas registros filtrados.
Sintaxe
SUBTOTAL(Função; Intervalo)
Função é um número que representa uma das seguintes funções:
Índice de funções (inclui valores não visíveis) |
Índice de Funções (ignora valores não visíveis) |
Função |
1 |
101 |
MÉDIA |
2 |
102 |
CONT.NÚM |
3 |
103 |
CONT.VALORES |
4 |
104 |
MÁXIMO |
5 |
105 |
MÍNIMO |
6 |
106 |
MULT |
7 |
107 |
DESVPAD |
8 |
108 |
DESVPADP |
9 |
109 |
SOMA |
10 |
110 |
VAR |
11 |
111 |
VARP |
Usa números de 1-11 para incluir linhas escondidas manualmente ou 101-111 para excluí-las; células filtradas são sempre excluídas.
Intervalo é o intervalo que inclui as células.
Exemplo
Você tem uma tabela no intervalo de células A1:B6, contendo uma lista de materiais para 10 estudantes. A linha 2 (Caneta) é escondida manualmente. Você quer ver a soma dos valores mostrados; ou seja, só o subtotal das linhas filtradas. Nesse caso a fórmula seria:
A |
B |
|
1 |
ITEM |
QUANTIDADE |
2 |
Caneta |
10 |
3 |
Lápis |
10 |
4 |
Caderno |
10 |
5 |
Borracha |
10 |
6 |
Apontador |
10 |
=SUBTOTAL(9;B2:B6) retorna 50.
=SUBTOTAL(109;B2:B6) retorna 40.
TAN
Retorna a tangente do ângulo (em radianos).
Sintaxe
TAN(Número)
Retorna a tangente (trigonométrica) do ângulo em radianos Número.
Para retornar a tangente de um ângulo em graus, use a função RADIANOS.
Exemplo
=TAN(PI()/4) retorna 1, a tangente de PI/4 radianos.
=TAN(RADIANOS(45)) retorna 1, a tangente de 45 graus.
TANH
Retorna a tangente hiperbólica de um número.
Sintaxe
TANH(Número)
Retorna a tangente hiperbólica de Número.
Exemplo
=TANH(0) retorna 0, a tangente hiperbólica de 0.
TETO
Arredonda um número para cima para o múltiplo da precisão mais próximo.
Sintaxe
TETO(Número; Precisão; Modo)
Número é o número que deverá ser arredondado para cima.
Precisão é o número para cujo múltiplo o valor será arredondado.
Modo é um parâmetro opcional. Se Modo for passado e não for igual a zero, e se os parâmetros Número e Precisão forem negativos, então o arredondamento será feito com base no valor absoluto do número, ou seja, os números negativos serão arredondados para um valor mais distante de zero. Se o parâmetro Modo for igual a zero ou omitido, os números negativos serão arredondados para um valor mais próximo de zero.
Se a planilha é exportada para o MS Excel, a função TETO é exportada para a função equivalente TETO.MAT que existe desde o Excel 2013. Se planeja utilizar a planilha com versões anteriores do Excel, utilize seja TETO.PRECISO que existe desde o Excel 2010, ou TETO.XCL que é exportado como função TETO compatível com todas as versões do Excel. Note que TETO.XCL sempre arredonda distanciando-se de zero. |
Exemplo
=TETO(-11;-2) retorna -10
=TETO(-11;-2;0) retorna -10
=TETO(-11;-2;1) retorna -12
TETO.PRECISO
Retorna um número arredondado para o número inteiro mais próximo ou para o múltiplo da precisão mais próximo, independentemente do sinal do número.
Sintaxe
TETO.PRECISO(Número; Precisão)
Número (obrigatório) é o número que deverá ser arredondado para cima.
Precisão (opcional) é o número para cujo múltiplo o valor será arredondado.
Exemplo
=TETO.PRECISO(-11;-2) retorna -10
TRUNCAR
Trunca um número ao remover casas decimais.
Sintaxe
TRUNCAR(Número; Cont)
Retorna Número com no máximo Cont casas decimais. As casas decimais excedentes são descartadas, independente do sinal.
TRUNCAR(Número; 0) se comporta como INT(Número) para números positivos, mas arredonda em direção ao zero com números negativos.
As casas decimais visíveis do resultado estão especificadas em LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular. |
Exemplo
=TRUNCAR(1,239;2) retorna 1,23. O 9 foi descartado.
=TRUNCAR(-1,234999;3) retorna -1,234. Todos os noves serão descartados.
ÍMPAR
Arredonda um número positivo para o número inteiro ímpar mais próximo superior e um número negativo para um número inteiro ímpar mais próximo inferior.
Sintaxe
ÍMPAR(Número)
Retorna Número arredondado para cima ao próximo inteiro ímpar.
Exemplo
=ÍMPAR(1,2) retorna 3.
=ÍMPAR(1) retorna 1.
=ÍMPAR(0) retorna 1.
=ÍMPAR(-3,1) retorna -5.